Anyone have a script to remove all the HP/Compaq agents after conversion?

[NJKwork]

Hi,

With both old school P2V and the new converter tool, we have to uninstall about 10 HP agents/tools from "Add/Remove Programs", manually uninstall the HP Network Configuration Utility, and delete two registry keys that "Add/Remove Programs" does not remove after the conversion is completed.

Does anyone have any sweet scripts or tools to do all this automatically?

Thanks

SlickBag

[NJKwork]

OK - this time I actually tested "before" posting!

Here is the updated batch file that "should" work with most versions of the HP agents. I also cleaned up some of the output. If you want more feedback from what is happening, remove some of the "/quiet" and other feedback limiting commands:

@ECHO OFF

ECHO HP Physcial to Virtual Cleaner Utility

ECHO Author: SlickBag

ECHO.

ECHO **********************************************************

ECHO * This batch file semi-automates the removal of the HP *

ECHO * software (agents and drivers) from a Virtaul server *

ECHO * that has been virtualized using P2V Helper, VMware *

ECHO * Converter, or similar software from an HP or Compaq *

ECHO * physical server. This batch file assumes relatively *

ECHO * newer versions of the support software, and may not *

ECHO * completely remove all the software for older versions. *

ECHO **********************************************************

ECHO.

ECHO Note - VMware Converter may leave some HP files corrupt.

ECHO You may want to run a "chkdisk" on the system drive

ECHO to fix any bad files before running this batch file.

ECHO.

ECHO USE AT YOUR OWN RISK!!!

ECHO.

ECHO *****************************

ECHO Type "ctrl-c" to quit now!!!

ECHO *****************************

ECHO.

ECHO USE AT YOUR OWN RISK!!!

Pause

cls

ECHO Removing the "HP Array Configuration Utility"...

"%PROGRAMFILES%\Compaq\Cpqacuxe\hpuninst.exe" /s

ECHO Removing the "HP Array Configuration Utility CLI"...

"%PROGRAMFILES%\Compaq\Hpacucli\hpuninst.exe" /s

ECHO Removing the "HP Array Diagnostic Utility"...

"%PROGRAMFILES%\Compaq\hpadu\hpuninst.exe" /s

ECHO Removing the "HP Insight Diagnostics Online Edition for Windows"...

If NOT Exist "%PROGRAMFILES%\InstallShield Installation Information\{3754251E-100C-47D4-AB86-DC34047EE3C4}\setup.exe" GOTO NEWDIAG

RunDll32 C:\PROGRA_1\COMMON1\INSTAL_{1\engine\6\INTEL3}1\Ctor.dll,LaunchSetup "C:\Program Files\InstallShield Installation Information\{3754251E-100C-47D4-AB86-DC34047EE3C4}\setup.exe" -l0x9 UNINSTALL

GOTO HPAGENTS

:NEWDIAG

MsiExec.exe /X\{04DDF575-93A4-4682-A4F1-ABD29ECDFE04} /quiet

:HPAGENTS

ECHO Removing the "HP Insight Management Agents"...

IF NOT Exist %SYSTEMROOT%\system32\CPQMgmt\aguninst.exe GOTO NEWAGENTS

%SYSTEMROOT%\system32\CPQMgmt\aguninst.exe /s

GOTO CHECKMP

:NEWAGENTS

MsiExec.exe /X\{DFB7A687-8111-4CC2-B175-9431708F7902} /quiet

:CHECKMP

ECHO Removing the "HP Lights-Out Online Configuration Utility"...

If NOT Exist "%PROGRAMFILES%\HP\hponcfg" GOTO CHECKIML

If NOT Exist "%PROGRAMFILES%\HP\hponcfg\hpuninst.exe" GOTO NEWMP

"%PROGRAMFILES%\HP\hponcfg\hpuninst.exe" /s

GOTO CHECKIML

:NEWMP

MsiExec.exe /X\{F8C40C34-FF8A-4A4D-8FA4-8DFF4503A61C} /quiet

:CHECKIML

ECHO Removing the "HP ProLiant Integrated Management Log Viewer"...

If NOT Exist "%PROGRAMFILES%\Compaq\Cpqimlv\hpuninst.exe" GOTO NEWIML

"%PROGRAMFILES%\Compaq\Cpqimlv\hpuninst.exe" /s

GOTO CHECKLPC

:NEWIML

MsiExec.exe /X\{B03AAFA3-07B7-4D93-8ECD-12B977BF861E} /quiet

:CHECKLPC

IF NOT Exist "%PROGRAMFILES%\Compaq\CpqLpcc\hpuninst.exe" GOTO NOLPC

ECHO Removing the "HP ProLiant Legacy Port Configuration Component"...

"%PROGRAMFILES%\Compaq\CpqLpcc\hpuninst.exe" /s

:NOLPC

If NOT Exist "%PROGRAMFILEs%\HPWBEM\IPMI" GOTO NOIPMI

ECHO Removing the "HP ProLiant IPMI WMI Provider"...

MsiExec.exe /X\{DF6412FA-0E25-4B23-9E80-116C061B4FD1} /quiet

:NOIPMI

ECHO Removing the "HP ProLiant Remote Monitor Service"...

If NOT Exist %SYSTEMROOT%\system32\hpuninst.exe GOTO NEWRMS

%SYSTEMROOT%\system32\hpuninst.exe /s

GOTO CHECKDP

:NEWRMS

MsiExec.exe /X\{0DEE841C-14D1-4497-8204-31B04370FDB7} /quiet

:CHECKDP

If NOT Exist C:\hp\hpsmh\data\htdocs\DataProtection\UnInstall.exe GOTO NODATAPROTECT

ECHO Removing the "HP Protect Your Data"...

C:\hp\hpsmh\data\htdocs\DataProtection\UnInstall.exe >Nul: 2>&1

:NODATAPROTECT

ECHO Removing the "HP Version Control Agent"...

IF NOT Exist C:\hp\hpsmh\data\cgi-bin\vcagent\vcaremov.exe GOTO NEWVCA

C:\hp\hpsmh\data\cgi-bin\vcagent\vcaremov.exe /silent C:\hp\hpsmh\data\cgi-bin\vcagent\vcagent.inf

GOTO CHECKSMH

:NEWVCA

MsiExec.exe /X\{5A5F45AE-0250-4C34-9D89-F10BDDEE665F} /quiet

:CHECKSMH

ECHO Removing the "HP System Management Homepage"...

RunDll32 C:\PROGRA_1\COMMON1\INSTAL_1\PROFES1\RunTime\11\00\Intel32\Ctor.dll,LaunchSetup "C:\Program Files\InstallShield Installation Information\{3C4DF0FD-95CF-4F7B-A816-97CEF616948F}\setup.exe" -l0x9 -removeonly

If NOT Exist "%PROGRAMFILES%\VMware\VMware Converter\InstMsi.exe" GOTO NOCONVERTER

ECHO Removing the "VMware Converter"...

MsiExec.exe /X\{A4D04B1A-DCF1-4C8C-8FFE-07D145812742} /quiet

:NOCONVERTER

ECHO Removing the "HP Network Congifuration Utility"...

snetcfg.exe -v -u cq_cpqteam >Nul: 2>&1

ECHO Removing registry keys for services without a "Removal Option"...

regedit /s p2vcleaner.reg

ECHO Deleting old HP and Compaq directories that are not needed...

rd /s/q c:\hp >Nul: 2>&1

rd /s/q c:\compaq >Nul: 2>&1

rd /s/q c:\cpqsystem >Nul: 2>&1

rd /s/q "%PROGRAMFILES%\compaq" >Nul: 2>&1

rd /s/q "%PROGRAMFILES%\hp" >Nul: 2>&1

rd /s/q %SYSTEMROOT%\system32\CPQMgmt >Nul: 2>&1

ECHO.

ECHO All software has been removed...please reboot.

PAUSE

and the REG file that must be in the same directory and called "p2vcleaner.reg":

Windows Registry Editor Version 5.00

SlickBag

[UK-ESX-User]

Just wanted to say thanks for coming up with a working solution for getting rid of the old Compaq/HP Agents - I've P2Ved several Compaq & HP ProLiant servers and the script works perfectly on all of them.

Cheers!!!

[NJKwork]

Hello again all you crazzzzzy P2Ver's. I have an updated script with some more error checking and new MSI uninstall strings (to account for the lastest HP Agents, such as 7.8 and 7.9). Its a moving target so it's not perfect yet and probably never will be, but here is is:

Oops - see next post...

[NJKwork]

Yikes - that is some nasty formating. Let me try again:

@ECHO OFF

ECHO HP Physcial to Virtual Cleaner Utility (Version 01-07-2008)

ECHO Author: HIDDEN

ECHO.

ECHO ************************************************************

ECHO * This batch file semi-automates the removal of management *

ECHO * agents and drivers from a virtual server that has been *

ECHO * virtualized from an HP or Compaq physical server using *

ECHO * P2V Helper, VMware Converter, or similar software. This *

ECHO * batch file assumes relatively newer versions of the HP *

ECHO * support software, and may not completely remove all the *

ECHO * software for older versions. *

ECHO ************************************************************

ECHO.

ECHO Note - The VMware Converter may leave some HP files corrupt.

ECHO You may want to run a "chkdisk" on the system drive

ECHO to fix any bad files before running this batch file.

ECHO.

ECHO USE AT YOUR OWN RISK!!!

ECHO.

ECHO *****************************

ECHO Type "ctrl-c" to quit now!!!

ECHO *****************************

ECHO.

ECHO USE AT YOUR OWN RISK!!!

Pause

cls

:ARRAYCONFIG

ECHO Removing the "HP Array Configuration Utility"...

If NOT Exist "%PROGRAMFILES%\Compaq\Cpqacuxe\hpuninst.exe" GOTO NEWARRAYCONFIG

"%PROGRAMFILES%\Compaq\Cpqacuxe\hpuninst.exe" /s

GOTO ARRAYCONFIGCLI

:NEWARRAYCONFIG

MsiExec.exe /X{836DF43A-9008-4334-9D08-6CB8D742BC74} /quiet

MsiExec.exe /X{0FC83811-F7AB-4D02-89EF-D86A7333C6C3} /quiet

:ARRAYCONFIGCLI

ECHO Removing the "HP Array Configuration Utility CLI"...

If NOT Exist "%PROGRAMFILES%\Compaq\Hpacucli\hpuninst.exe" GOTO NEWARRAYCONFIGCLI

"%PROGRAMFILES%\Compaq\Hpacucli\hpuninst.exe" /s

GOTO ARRAYDIAG

:NEWARRAYCONFIGCLI

MsiExec.exe /X{4C22F82F-389B-41C4-BD8E-96D5F3EAB5D9} /quiet

MsiExec.exe /X{FC1534DB-31FE-4994-A91C-120A9AB7CE17} /quiet

:ARRAYDIAG

ECHO Removing the "HP Array Diagnostic Utility"...

If NOT Exist "%PROGRAMFILES%\Compaq\hpadu\hpuninst.exe" GOTO NEWARRAYDIAG

"%PROGRAMFILES%\Compaq\hpadu\hpuninst.exe" /s

GOTO DIAG

:NEWARRAYDIAG

MsiExec.exe /X{6FB456CA-B4B4-4B17-9CDD-A05B4E882E06} /quiet

MsiExec.exe /X{E66B176F-F12D-45D9-9125-CC66C53FCB5C} /quiet

:DIAG

ECHO Removing the "HP Insight Diagnostics Online Edition for Windows"...

If NOT Exist "%PROGRAMFILES%\InstallShield Installation Information\{3754251E-100C-47D4-AB86-DC34047EE3C4}\setup.exe" GOTO NEWDIAG

RunDll32 C:\PROGRA_1\COMMON1\INSTAL_{1\engine\6\INTEL3}1\Ctor.dll,LaunchSetup "C:\Program Files\InstallShield Installation

Information\{3754251E-100C-47D4-AB86-DC34047EE3C4}\setup.exe" -l0x9 UNINSTALL

:NEWDIAG

MsiExec.exe /X{04DDF575-93A4-4682-A4F1-ABD29ECDFE04} /quiet

MsiExec.exe /X{97D259B9-2076-4C25-97E1-440D9D038229} /quiet

:HPAGENTS

ECHO Removing the "HP Insight Management Agents"...

If NOT Exist %SYSTEMROOT%\system32\CPQMgmt\aguninst.exe GOTO NEWAGENTS

%SYSTEMROOT%\system32\CPQMgmt\aguninst.exe /s

GOTO CHECKMP

:NEWAGENTS

MsiExec.exe /X{DFB7A687-8111-4CC2-B175-9431708F7902} /quiet

MsiExec.exe /X{869F01A1-DB56-4876-8752-2C835BB6AB53} /quiet

MsiExec.exe /X{50B62114-7AFE-4428-A778-16BFA8E93044} /quiet

:CHECKMP

ECHO Removing the "HP Lights-Out Online Configuration Utility"...

If NOT Exist "%PROGRAMFILES%\HP\hponcfg" GOTO CHECKIML

If NOT Exist "%PROGRAMFILES%\HP\hponcfg\hpuninst.exe" GOTO NEWMP

"%PROGRAMFILES%\HP\hponcfg\hpuninst.exe" /s

GOTO CHECKIML

:NEWMP

MsiExec.exe /X{F8C40C34-FF8A-4A4D-8FA4-8DFF4503A61C} /quiet

MsiExec.exe /X{F1FA13C8-E4D8-45E4-B1A1-1984FE50B7F7} /quiet

:CHECKIML

ECHO Removing the "HP ProLiant Integrated Management Log Viewer"...

If NOT Exist "%PROGRAMFILES%\Compaq\Cpqimlv\hpuninst.exe" GOTO NEWIML

"%PROGRAMFILES%\Compaq\Cpqimlv\hpuninst.exe" /s

GOTO CHECKLPC

:NEWIML

MsiExec.exe /X{B03AAFA3-07B7-4D93-8ECD-12B977BF861E} /quiet

MsiExec.exe /X{1FCDA905-9C8F-4544-84C0-106CDAB7842C} /quiet

MsiExec.exe /X{4F8D40CA-D8AB-4AA6-B47D-AA8FA845E530} /quiet

:CHECKLPC

If NOT Exist "%PROGRAMFILES%\Compaq\CpqLpcc\hpuninst.exe" GOTO NOLPC

ECHO Removing the "HP ProLiant Legacy Port Configuration Component"...

"%PROGRAMFILES%\Compaq\CpqLpcc\hpuninst.exe" /s

:NOLPC

If NOT Exist "%PROGRAMFILEs%\HPWBEM\IPMI" GOTO NOIPMI

ECHO Removing the "HP ProLiant IPMI WMI Provider"...

MsiExec.exe /X{DF6412FA-0E25-4B23-9E80-116C061B4FD1} /quiet

MsiExec.exe /X{6BD49497-AFE5-43D4-9B7B-AAD7B405E110} /quiet

:NOIPMI

ECHO Removing the "HP ProLiant Remote Monitor Service"...

If NOT Exist %SYSTEMROOT%\system32\hpuninst.exe GOTO NEWRMS

%SYSTEMROOT%\system32\hpuninst.exe /s

GOTO CHECKDP

:NEWRMS

MsiExec.exe /X{0DEE841C-14D1-4497-8204-31B04370FDB7} /quiet

MsiExec.exe /X{8562966D-9ACB-4496-A443-378C6E4A50BA} /quiet

MsiExec.exe /X{93EF387B-6884-4ADE-806E-E98F05DD2A4C} /quiet

:CHECKDP

If NOT Exist C:\hp\hpsmh\data\htdocs\DataProtection\UnInstall.exe GOTO NODATAPROTECT

ECHO Removing the "HP Protect Your Data"...

C:\hp\hpsmh\data\htdocs\DataProtection\UnInstall.exe >Nul: 2>&1

:NODATAPROTECT

ECHO Removing the "HP Version Control Agent"...

If NOT Exist C:\hp\hpsmh\data\cgi-bin\vcagent\vcaremov.exe GOTO NEWVCA

C:\hp\hpsmh\data\cgi-bin\vcagent\vcaremov.exe /silent C:\hp\hpsmh\data\cgi-bin\vcagent\vcagent.inf

GOTO CHECKSMH

:NEWVCA

MsiExec.exe /X{5A5F45AE-0250-4C34-9D89-F10BDDEE665F} /quiet

:CHECKSMH

ECHO Removing the "HP System Management Homepage"...

If NOT Exist "C:\PROGRA_1\COMMON1\INSTAL_1\PROFES1\RunTime\11\00\Intel32\Ctor.dll" GOTO NEWHP

If NOT Exist "C:\Program Files\InstallShield Installation Information\{3C4DF0FD-95CF-4F7B-A816-97CEF616948F}\setup.exe" GOTO NEWHP

RunDll32 C:\PROGRA_1\COMMON1\INSTAL_1\PROFES1\RunTime\11\00\Intel32\Ctor.dll,LaunchSetup "C:\Program Files\InstallShield Installation

Information\{3C4DF0FD-95CF-4F7B-A816-97CEF616948F}\setup.exe" -l0x9 -removeonly

:NEWHP

"C:\Program Files\InstallShield Installation Information\{3C4DF0FD-95CF-4F7B-A816-97CEF616948F}\setup.exe"

:ARRAYDME

Echo Removing the "HP ProLiant Smart Array Device Manager Extension"...

MsiExec.exe /X{4FE559EC-C5CC-40AB-A7BE-A03C21ACCD2D} /quiet

MsiExec.exe /X{5B9E3229-A5B3-459B-8B96-BA52A63BB140} /quiet

If NOT Exist "%PROGRAMFILES%\VMware\VMware Converter\InstMsi.exe" GOTO NOCONVERTER

ECHO Removing the "VMware Converter"...

MsiExec.exe /X{A4D04B1A-DCF1-4C8C-8FFE-07D145812742} /quiet

MsiExec.exe /X{EF8B6B5D-A38C-431A-81FF-2C8E3215C6A2} /quiet

:NOCONVERTER

ECHO Removing the "HP Network Congifuration Utility"...

snetcfg.exe -v -u cq_cpqteam >Nul: 2>&1

ECHO Removing registry keys for services without a "Removal Option"...

regedit /s p2vcleaner.reg

ECHO Deleting old HP and Compaq directories that are not needed...

rd /s/q c:\hp >Nul: 2>&1

rd /s/q c:\compaq >Nul: 2>&1

rd /s/q c:\cpqsystem >Nul: 2>&1

rd /s/q "%PROGRAMFILES%\compaq" >Nul: 2>&1

rd /s/q "%PROGRAMFILES%\hp" >Nul: 2>&1

rd /s/q %SYSTEMROOT%\system32\CPQMgmt >Nul: 2>&1

ECHO.

ECHO All software has been removed...please reboot.

PAUSE

[jhirsh]

Hey folks, nice work on the script. I noticed that there's a typo in the latest version you posted under the section for the System Management Homepage/NEWHP. You're missing a "/" between the InstallShield folder and the CLSID folder name. Also, as an alternative for the registry cleanup, you could call the commmand "sc delete sysdown". The SC command is available in W2003, or available as a part of the resource kit for earlier releases. If you prefer to use the registry file, you might also want to include the key HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Enum\Root\LEGACY_SYSDOWN.

As a side note, I've found the P2V process to be a lot smoother if you disable the HP services on the target server prior to starting your image (the HP Insight Server Agents service in particular). On the majority of my HP servers, this process would max out the CPU of the VM guest until it was killed.

Cheers,

-Joshua

[NJKwork]

Awesome! Thank you very much for finding the typo error and the suggestion on the registry thing. I am always looking for ways to improve this.

And "yep" on the HP services thing. I too stop (and disable) those as well as Symantec services prior to the conversion.

Take care!

[NJKwork]

Interesting, I went back to check my script and the "backslashes" are there...yet they got missed when I copied and pasted them into this posting. Not sure how that happened; very wierd.

[jcerroni]

Great Thread. Thanks for the information. I decided to go with a slightly different approach and want to show it to you. I created a vbscript that does the following:

1. Reads a list of programs to uninstall from a file (listed by display name) called HPList.txt located in the same directory as this script

2. Reads all the uninstall registry subkeys and stores the display name and uninstall string

3. Sorts the stored registry information in descending order so the GUID keys are last

4. Compares the two lists and runs the uninstall program for any matches.

Note: You may get some messages that says program not installed. That's because there may be multiple reg keys. One under the name and one under the GUID.

The reason why I chose to do it this way, is that it's less version specific. As long as the display name doesn't change it should work.

The script is a little messy and it needs cleaned up, but it seems to work for me.

I attached a zip file containing the script and the HPlist that has most of the programs that need removed.

Any comments or suggstions are appreciated.

[NJKwork]

Awesome! Looks very cool. I will be checking it out shortly.

S.B.

[jcerroni]

I'm an idiot.

I didn't see page two of this thread. I can add the manual uninstalls like the network configuration utility as well as removing excess registry keys and files.

I'm not sure when though. I wasted an awful lot of time doing what I did so far.

[jcerroni]

OK. I made some changes:

I renamed the HPlist.txt to HPAutoList.txt and adde HPManList.txt (manual)

Inside the HPManList.txt you can add hopefully any command lines, like you would be able to in a batch file.

I also fixed some other problems.

One issue left open is that some of the uninstall strings in the registry might error out. The reason has to do with spaces in the paths when there is in argument with the exe.

I still have to work on that. I attached the new files.

[dustant]

Can you post the snetcfg.exe since the download link no longer works? I'm trying to get rid of the HP Network that doesn't seem to want to uninstall/stop.

[mdswen]

Why not use netcfg?

[Lawrence]

Comment regarding the CPU impact of the HP services in a VM

I have seen this as well, and created the script below to deal with that. I also found that this CPU impact does NOT happen when the VM is on a HP server ESX host (at least when the going from a DL380G4 physical to a DL380G5 ESX host)

I left the serivces installed (1 didn't have time or interest for a lab environment to uninstall, 2 with thoughts of V2P desirable to leave items installed.)

This CMD script is run on Windows 2003 Server SP1

@echo off

REM Created Feb 13 2008 by Lawrence Dee

REM-----

REM INSTRUCTIONS:

REM This is a script to disable the HP services

REM to ease use in a Virtual Machine

REM-----

REM - Set services to Manual (='demand' in SC) rather than Auto start

pause

sc config "Cissesrv" start= demand

sc config "CpqNicMgmt" start= demand

sc config "CpqRcmc" start= demand

sc config "cpqvcagent" start= demand

sc config "cqmghost" start= demand

sc config "CqMgServ" start= demand

sc config "CqMgStor" start= demand

sc config "sysdown" start= demand

sc config "SysMgmtHp" start= demand

:STOPServices

REM - stop services

sc stop "Cissesrv"

sc stop "CpqNicMgmt"

sc stop "CpqRcmc"

sc stop "cpqvcagent"

sc stop "cqmghost"

sc stop "CqMgServ"

sc stop "CqMgStor"

sc stop "sysdown"

sc stop "SysMgmtHp"

pause

GOTO EXIT

REM Notes and descriptions from SC Query

SERVICE_NAME: Cissesrv

DISPLAY_NAME: HP Smart Array SAS/SATA Event Notification Service

SERVICE_NAME: CpqNicMgmt

DISPLAY_NAME: HP Insight NIC Agents

SERVICE_NAME: CpqRcmc

DISPLAY_NAME: HP ProLiant Remote Monitor Service

SERVICE_NAME: cpqvcagent

DISPLAY_NAME: HP Version Control Agent

SERVICE_NAME: CqMgServ

DISPLAY_NAME: HP Insight Server Agents

SERVICE_NAME: CqMgStor

DISPLAY_NAME: HP Insight Storage Agents

SERVICE_NAME: sysdown

DISPLAY_NAME: HP ProLiant System Shutdown Service

SERVICE_NAME: SysMgmtHp

DISPLAY_NAME: HP System Management Homepage

REM - not listed in SC Query

cqmghost.exe

HP Insight Foundation Agents

:EXIT

[mbs01]

Same here, can't find snetcfg.exe anyway

Other question: I see a lot of services like cpqasm, cpqphp etc...

Which of these can be deleted? Do I need to delete these or don't they harm?

Script is great, deletes almost all software

thx!

[NJKwork]

Sorry guys, regarding the snetcfg.exe, I just don't feel comfortable posting software that I do not legally own. I know lots of people do it, and it would problably be OK, but I would rather not take the chance and get into legal trouble for it.

I will dig around and see if I can find a site hosting it again.

SB

[NJKwork]

I sent this email to Evan, who I believe wrote the utility. Waiting to see if he can provide us a new link:

Hi Evan,

A few of us have been using your snetcfg.exe utility to do some post P2V cleanup (converting HP servers to VMware virtual servers). However the link to your utility no longer works:

http://www.jsifaq.com/docs/files/76011/snetcfg.zip

Some people on the VMware forums are looking for this utility, and I did not feel comfortable just sending it to them, for legal reasons. I was wondering if you could provide us a link to where we can download it again.

SB

[hfourie]

First,

Thanks to all for the helpfull script. This has taken me ages to do normally. Will try the script soon, but seems like it works fine from others comments.

Don't know it you managed to find an easy solution to the "uninstall HP Networking" issue yet, but here is how I do it. And if you script the Agent uninstall, this shouldnt be such a big problem to do "manually".

Go into the Nic'sproperties, and there you see IP , HP Networking, etc. Click HP Networking and uninstall. It reboots, and away you go.

[NJKwork]

Yep - you can always remove it manually following the instructions you provided. I was just trying to automate all of it, so I was using the SNETCFG to allow that portion to be scripted as well. It does work - assumming you have the SNETCFG utility

SB

[NJKwork]

Here is an updated version of my batch file. It includes updates for the HP 8.00 Support Pack, including the new WBEM agents (although not quiet, as it uses a VB file to do the uninstall). I have also cleaned up some of the labels - I was a bit inconsistent earlier in my naming standards. It is somewhat tested...use at your own risk

@ECHO OFF

ECHO HP Physcial to Virtual Cleaner Utility (Version 04-25-2008)

ECHO Author: SlickBag

ECHO.

ECHO ***********************************************************************

ECHO * This batch file semi-automates the removal of management

ECHO * agents and drivers from a virtual server that has been

ECHO * virtualized from an HP or Compaq physical server using

ECHO * P2V Helper, VMware Converter, or similar software. This

ECHO * batch file assumes relatively newer versions of the HP

ECHO * support software, and may not completely remove all the

ECHO * software for older versions.

ECHO ***********************************************************************

ECHO.

ECHO Note - The VMware Converter may leave some HP files corrupt.

ECHO You may want to run a "chkdisk" on the system drive

ECHO to fix any bad files before running this batch file.

ECHO.

ECHO USE AT YOUR OWN RISK!!!

ECHO.

ECHO *****************************

ECHO Type "ctrl-c" to quit now!!!

ECHO *****************************

ECHO.

ECHO USE AT YOUR OWN RISK!!!

Pause

cls

:OLDARRAYCONFIG

ECHO Removing the "HP Array Configuration Utility"...

If NOT Exist "%PROGRAMFILES%\Compaq\Cpqacuxe\hpuninst.exe" GOTO NEWARRAYCONFIG

"%PROGRAMFILES%\Compaq\Cpqacuxe\hpuninst.exe" /s

GOTO OLDARRAYCONFIGCLI

:NEWARRAYCONFIG

MsiExec.exe /X{836DF43A-9008-4334-9D08-6CB8D742BC74} /quiet

MsiExec.exe /X{0FC83811-F7AB-4D02-89EF-D86A7333C6C3} /quiet

MsiExec.exe /X{52C53F6F-9F0B-4333-BA38-35DB5BE7C12E} /quiet

:OLDARRAYCONFIGCLI

ECHO Removing the "HP Array Configuration Utility CLI"...

If NOT Exist "%PROGRAMFILES%\Compaq\Hpacucli\hpuninst.exe" GOTO NEWARRAYCONFIGCLI

"%PROGRAMFILES%\Compaq\Hpacucli\hpuninst.exe" /s

GOTO OLDARRAYDIAG

:NEWARRAYCONFIGCLI

MsiExec.exe /X{4C22F82F-389B-41C4-BD8E-96D5F3EAB5D9} /quiet

MsiExec.exe /X{FC1534DB-31FE-4994-A91C-120A9AB7CE17} /quiet

MsiExec.exe /X{34134D3E-AE5E-4CA5-A1DE-B0A3D9C19F77} /quiet

:OLDARRAYDIAG

ECHO Removing the "HP Array Diagnostic Utility"...

If NOT Exist "%PROGRAMFILES%\Compaq\hpadu\hpuninst.exe" GOTO NEWARRAYDIAG

"%PROGRAMFILES%\Compaq\hpadu\hpuninst.exe" /s

GOTO SAENS

:NEWARRAYDIAG

MsiExec.exe /X{6FB456CA-B4B4-4B17-9CDD-A05B4E882E06} /quiet

MsiExec.exe /X{E66B176F-F12D-45D9-9125-CC66C53FCB5C} /quiet

MsiExec.exe /X{D7B169BD-D8BF-4520-B519-81F85AD91843} /quiet

:SAENS

If NOT Exist "%PROGRAMFILES%\HP\Cissesrv\cissesrv.exe" GOTO OLDDIAG

Echo Removing the "HP Smart Array SAS/SATA Event Notification Service"...

MsiExec.exe /X{2FB2F62B-C28F-43BA-82FC-6E782807B195} /quiet

:OLDDIAG

ECHO Removing the "HP Insight Diagnostics Online Edition for Windows"...

If NOT Exist "%PROGRAMFILES%\InstallShield Installation Information\{3754251E-100C-47D4-AB86-DC34047EE3C4}\setup.exe" GOTO NEWDIAG

RunDll32 C:\PROGRA_1\COMMON1\INSTAL_{1\engine\6\INTEL3}1\Ctor.dll,LaunchSetup "C:\Program Files\InstallShield Installation Information\{3754251E-100C-47D4-AB86-DC34047EE3C4}\setup.exe" -l0x9 UNINSTALL

:NEWDIAG

MsiExec.exe /X{04DDF575-93A4-4682-A4F1-ABD29ECDFE04} /quiet

MsiExec.exe /X{97D259B9-2076-4C25-97E1-440D9D038229} /quiet

:OLDHPAGENTS

ECHO Removing the "HP Insight Management Agents"...

If NOT Exist %SYSTEMROOT%\system32\CPQMgmt\aguninst.exe GOTO NEWHPAGENTS

%SYSTEMROOT%\system32\CPQMgmt\aguninst.exe /s

GOTO OLDHPONCFG

:NEWHPAGENTS

MsiExec.exe /X{DFB7A687-8111-4CC2-B175-9431708F7902} /quiet

MsiExec.exe /X{869F01A1-DB56-4876-8752-2C835BB6AB53} /quiet

MsiExec.exe /X{50B62114-7AFE-4428-A778-16BFA8E93044} /quiet

:OLDHPONCFG

ECHO Removing the "HP Lights-Out Online Configuration Utility"...

If NOT Exist "%PROGRAMFILES%\HP\hponcfg" GOTO CHECKIML

If NOT Exist "%PROGRAMFILES%\HP\hponcfg\hpuninst.exe" GOTO NEWHPONCFG

"%PROGRAMFILES%\HP\hponcfg\hpuninst.exe" /s

GOTO OLDIML

:NEWHPONCFG

MsiExec.exe /X{F8C40C34-FF8A-4A4D-8FA4-8DFF4503A61C} /quiet

MsiExec.exe /X{F1FA13C8-E4D8-45E4-B1A1-1984FE50B7F7} /quiet

MsiExec.exe /X{2343987D-E96B-4670-96F6-99270DFC2F5F} /quiet

:OLDIML

ECHO Removing the "HP ProLiant Integrated Management Log Viewer"...

If NOT Exist "%PROGRAMFILES%\Compaq\Cpqimlv\hpuninst.exe" GOTO NEWIML

"%PROGRAMFILES%\Compaq\Cpqimlv\hpuninst.exe" /s

GOTO LPC

:NEWIML

MsiExec.exe /X{B03AAFA3-07B7-4D93-8ECD-12B977BF861E} /quiet

MsiExec.exe /X{1FCDA905-9C8F-4544-84C0-106CDAB7842C} /quiet

MsiExec.exe /X{4F8D40CA-D8AB-4AA6-B47D-AA8FA845E530} /quiet

MsiExec.exe /X{949F1167-A591-4DFE-944A-8D1FC68896D4} /quiet

:LPC

If NOT Exist "%PROGRAMFILES%\Compaq\CpqLpcc\hpuninst.exe" GOTO IPMI

ECHO Removing the "HP ProLiant Legacy Port Configuration Component"...

"%PROGRAMFILES%\Compaq\CpqLpcc\hpuninst.exe" /s

:IPMI

If NOT Exist "%PROGRAMFILEs%\HPWBEM\IPMI" GOTO OLDRMS

ECHO Removing the "HP ProLiant IPMI WMI Provider"...

MsiExec.exe /X{DF6412FA-0E25-4B23-9E80-116C061B4FD1} /quiet

MsiExec.exe /X{6BD49497-AFE5-43D4-9B7B-AAD7B405E110} /quiet

:OLDRMS

ECHO Removing the "HP ProLiant Remote Monitor Service"...

If NOT Exist %SYSTEMROOT%\system32\hpuninst.exe GOTO NEWRMS

%SYSTEMROOT%\system32\hpuninst.exe /s

GOTO DP

:NEWRMS

MsiExec.exe /X{0DEE841C-14D1-4497-8204-31B04370FDB7} /quiet

MsiExec.exe /X{8562966D-9ACB-4496-A443-378C6E4A50BA} /quiet

MsiExec.exe /X{93EF387B-6884-4ADE-806E-E98F05DD2A4C} /quiet

MsiExec.exe /X{28F48D1F-C815-4236-BD96-1644263EC1DF} /quiet

:DP

If NOT Exist C:\hp\hpsmh\data\htdocs\DataProtection\UnInstall.exe GOTO OLDHPVCA

ECHO Removing the "HP Protect Your Data"...

C:\hp\hpsmh\data\htdocs\DataProtection\UnInstall.exe >Nul: 2>&1

:OLDHPVCA

ECHO Removing the "HP Version Control Agent"...

If NOT Exist C:\hp\hpsmh\data\cgi-bin\vcagent\vcaremov.exe GOTO NEWHPVCA

C:\hp\hpsmh\data\cgi-bin\vcagent\vcaremov.exe /silent C:\hp\hpsmh\data\cgi-bin\vcagent\vcagent.inf

GOTO OLDSMH

:NEWHPVCA

MsiExec.exe /X{5A5F45AE-0250-4C34-9D89-F10BDDEE665F} /quiet

:OLDSMH

ECHO Removing the "HP System Management Homepage"...

If NOT Exist "C:\PROGRA_1\COMMON1\INSTAL_1\PROFES1\RunTime\11\00\Intel32\Ctor.dll" GOTO NEWSMH

If NOT Exist "C:\Program Files\InstallShield Installation Information\{3C4DF0FD-95CF-4F7B-A816-97CEF616948F}\setup.exe" GOTO NEWSMH

RunDll32 C:\PROGRA_1\COMMON1\INSTAL_1\PROFES1\RunTime\11\00\Intel32\Ctor.dll,LaunchSetup "C:\Program Files\InstallShield Installation Information\{3C4DF0FD-95CF-4F7B-A816-97CEF616948F}\setup.exe" -l0x9 -removeonly

:NEWSMH

"C:\Program Files\InstallShield Installation Information\{3C4DF0FD-95CF-4F7B-A816-97CEF616948F}\setup.exe"

:ARRAYDME

Echo Removing the "HP ProLiant Smart Array Device Manager Extension"...

MsiExec.exe /X{4FE559EC-C5CC-40AB-A7BE-A03C21ACCD2D} /quiet

MsiExec.exe /X{5B9E3229-A5B3-459B-8B96-BA52A63BB140} /quiet

If NOT Exist "%PROGRAMFILES%\VMware\VMware Converter\InstMsi.exe" GOTO HPWBEM

ECHO Removing the "VMware Converter"...

MsiExec.exe /X{A4D04B1A-DCF1-4C8C-8FFE-07D145812742} /quiet

MsiExec.exe /X{EF8B6B5D-A38C-431A-81FF-2C8E3215C6A2} /quiet

:HPWBEM

If NOT Exist C:\CPQSYSTEM\uninstall\CB9CC4E0-ACBF-40C9-B1EF-F28CDF47486D.vbs GOTO HEADLESS

ECHO Removing the "HP Insight Management WBEM Providers"...

wscript.exe "C:\CPQSYSTEM\uninstall\CB9CC4E0-ACBF-40C9-B1EF-F28CDF47486D.vbs"

:HEADLESS

Echo Removing the "Headless Server Registry Update"...

MsiExec.exe /X{4E5563B6-DE0A-4F3B-A5D6-15789FD12D9B} /quiet

:HPNETCFG

ECHO Removing the "HP Network Congifuration Utility"...

snetcfg.exe -v -u cq_cpqteam >Nul: 2>&1

ECHO Removing registry keys for services without a "Removal Option"...

regedit /s p2vcleaner.reg

ECHO Deleting old HP and Compaq directories that are not needed...

rd /s/q c:\hp >Nul: 2>&1

rd /s/q c:\compaq >Nul: 2>&1

rd /s/q c:\cpqsystem >Nul: 2>&1

rd /s/q "%PROGRAMFILES%\compaq" >Nul: 2>&1

rd /s/q "%PROGRAMFILES%\hp" >Nul: 2>&1

rd /s/q %SYSTEMROOT%\system32\CPQMgmt >Nul: 2>&1

ECHO.

ECHO All software has been removed...please reboot.

PAUSE

Enjoy!

SB