these are are duplicates of the services - but i also have in task manager

vmware-tray.exe and hqtray.exe - which i can't seem to find a related service for?

from what i've read i can disable the vmauthd.exe service (or maybe set to manual) as i am a single user running as an admin ?

I probably don't need vmware-ufad.exe but as it is already set to manual it's probably not running and would only be run/active if i used the Converter, so i could leave this as is?

i have a simple home network setup, wireless router, couple of pcs, i set the pcs to use static ips, and i have the VM using Bridged mode (i also set up a static ip via the settings of the OS that is running in the VM) so i believe i can disable (or set to manual) vmnat.exe ?

vmount2.exe seems important so leave alone! ??

which leaves me with vmnetdhcp.exe - looking at what i explained earlier about my network and how i run the VM , is it needed? and could i set it to disabled or manual?

hqtray.exe - VMware Host Network Access Status Tray Application - not sure if i need this running or what it does ??

and finally

vmware-tray.exe for which i can't find a corresponding service but it has an entry in the reg to run on startup - this seems to be something to do with running a VM still, even if you have closed down the workstation control panel??

As i don't ever do this i take it i can either disable this from startup ??

I'm using a pc with limited resources at the moment and all these running processes are consuming aprox 38mb and i've noticed xp is a fair bit slower booting up.

If possible i'd like to try and see what i can disable so any help would be appreciated.

thanks.

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' This script first starts services for VMWARE, then starts VMWARE Workstation.
' Once VMWARE stops, services are stopped and terminated again.
' Prerequisites for this script:
' Modify: Computer Management -> Services -> VMware Virtual Mount Manager Extended ->Startup Type:Manual
' Modify: Computer Management -> Services -> VMware Nat Service ->Startup Type:Manual
' Modify: Computer Management -> Services -> VMware DHCP Service ->Startup Type:Manual
' Modify: Computer Management -> Services -> VMware Authorization Service ->Startup Type:Manual
' Remove HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\VMware hqtray
' Remove HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\vmware-tray
'
' written 080821 by w_m0zart / Marc Nijdam. http://www.nijdam.de/marc.html
'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Set FSO = CreateObject("Scripting.FileSystemObject")
Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
 
dim pth
dim pgm1
dim pgm2
dim pgm3
dim cmnd
dim qq
 
set shell = Wscript.CreateObject("Wscript.shell") 
 
qq = Chr(34) ' define quote as constant, because shell.run does not accept a program without this function
 
' Program to start with command line options
pth = "C:\Program Files\VMware\VMware Workstation\"
pgm1 = "vmware.exe"
pgm2 = "hqtray.exe"
pgm3 = "vmware-tray.exe"
cmnd = ""
rem Now starting services
startservice ("VMAuthdService")
startservice ("VMnetDHCP")
startservice ("VMware NAT Service")
startservice ("vmount2")
shell.run qq & pth & pgm2 & qq,0,false
shell.run qq & pth & pgm3 & qq,0,false
 
shell.run qq & pth & pgm1 & qq & cmnd,1,true ' now starting vmware.exe
 
rem Now stopping services
stopservice ("VMAuthdService")
stopservice ("VMware NAT Service")
stopservice ("vmount2")
stopservice ("VMnetDHCP")
termService ("hqtray.exe") ' service which cannot be stopped with the function stopservice (...)
termService ("vmware-tray.exe") ' service which cannot be stopped with the function stopservice (...)
 
rem Removing registry key
shell.RegDelete( "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run\vmware-tray") ' And remove the key again from the registry, since vmware has written this back
 
 
sub startservice (StrService) ' Start a service with its service name in the Windows Services (via Computer Management)
	c = 0
	Do Until c = 1
		Set colServiceList = objWMIService.ExecQuery _
			("Select * from Win32_Service where Name = '" & StrService & "'")
		For Each objService in colServiceList
			Select Case objService.State
				Case "Stopped"
					objService.StartService()
					c = 1
				Case "Running"
					c = 0
				Case "Start Pending"
					c = 0
			End Select
		Next
		WScript.Sleep (1000)
	Loop
End Sub
 
sub stopservice (StrService) ' Stop a service with its service name in the Windows Services (via Computer Management)
	c = 0
	Do Until c = 1
		Set colServiceList = objWMIService.ExecQuery _
			("Select * from Win32_Service where Name = '" & StrService & "'")
		For Each objService in colServiceList
			Select Case objService.State
				Case "Stopped"
					c = 1
				Case "Running"
					objService.StopService()
					c = 0
				Case "Start Pending"
					c = 0
			End Select
		Next
		WScript.Sleep (1000)
	Loop
End Sub
 
sub termService (StrService) ' Stop a service with name StrService corresponding in the Windows Task Manager
	Dim colProcessList, objProcess
	Set colProcessList = GetObject("Winmgmts:").ExecQuery("Select * from Win32_Process Where Name ='" & StrService & "'")
	For Each objProcess in colProcessList
    		objProcess.Terminate( )
	Next
End sub